***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec 13, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJD100N04-AU   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = 1.8		 kp = 65.5	)
.model  dds   d(
+   is = 1.294e-11	  n = 1.016		   rs = 3.000e-3
+   eg = 1.000	     trs1 = 1.308e-3 )
.model  dbody d(
+   is = 1.294e-11	  n = 1.016		   rs = 3.000e-3
+   eg = 1.000	     trs1 = 1.308e-3 
+  cjo = 1.322e-9	 	  m = 1.923e-0	   vj = 9.990e-0
+   bv = 44			ibv = 250e-6	 tbv1 = 7.805e-4		tbv2 = -2.207e-7
+   tt = 25n)
.model  inter  nmos(
+  vto = 0			 kp = 10		level = 1)
.model  dgd   d(
+  cjo = 1.503e-9		  m = 4.896e-1	   vj = 6.276e-1)
.param
+  cgs = 6.892e-9		cgd = 1.486e-9
+   rd = 1.000e-4		 ra = 1.000e-4	 trd1 = 9.375e-3		trd2 = 8.085e-6
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}    ic = 0
egv	 2t   3   table   {v(1t, S)} 
+((0.00 , 0.00 ),
+ (0.50 , 0.50 ),
+ (1.00 , 1.00 ),
+ (1.50 , 1.50 ),
+ (2.50 , 2.30 ),
+ (2.80 , 2.55 ),
+ (3.50 , 6.00 ),
+ (4.00 , 7.50 ),
+ (4.50 , 8.20 ),
+ (5.00 , 8.80 ),
+ (6.00 , 9.40 ),
+ (8.00 , 9.80 ),
+ (10.0 , 10.0 ),
+ (20.0 , 10.1 ),
+ (22.0 , 10.1 ))
egt	  1  2t   value = {4.027e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1},{trd2}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4  1t   2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$
